//@version=5
indicator('Pine script Starter for Aleeert', overlay=true)


// CONTROLS --------------------------------------------------------

pair = input('BTCUSDT', 'Pair')
leverage = input.int(5, 'Leverage', options=[1, 2, 3, 5, 10, 20, 50, 75, 100, 125])
qty = input.string('$10', 'Qty', tooltip='Example: $10 x5 leverage equal to order size of $50. Another allowed formats: percent of balance e.g. 100%, and fixed number of coins e.g. 0.1')
priceType = input.string('stop-limit', 'Price type', options=['market', 'stop-limit'], tooltip='Order will be placed with market or limit price. Stop Limit price will be equal to "close" price at the moment of triggering')
istpsl = input.bool(false, 'TP/SL', tooltip='Note: For using TP/SL on Spot the "market" price type is required')
tp = input.float(1.5, 'TP, %', minval=0.1, step=0.1, tooltip='Take Profit level')
sl = input.float(0.5, 'SL, %', minval=0.1, step=0.1, tooltip='Stop Loss level')
slot = input.int(1, 'Slot ID', minval=1, step=1, tooltip='Pointer to the market where the order must be placed')
userkey = input('', 'Aleeert userkey')
comment = 'Pine script Starter'
command1 = ''
command2 = ''  // optionally


// STRATEGY IDEA ---------------------------------------------------

// WARNING!
// THIS IDEA WAS CREATED FOR DEMONSTRATION ONLY. USE OF THIS DEMO 
// "AS IS" FOR REAL TRADING MAY CAUSE LOSSES. MODIFY AND USE AT 
// YOUR OWN RISK.
// The trading idea is simple and based on the RSI indicator. We 
// will place long orders if RSI crosses 30 and we will place short 
// orders if RSI crosses below 70. Before placing a new order, we 
// will close the current position (if any) and cancel limit orders 
// (if any). Repeated signals will be ignored until a return signal 
// is received. The alert will be triggered when the candle closes.


// STRATEGY VARS ---------------------------------------------------

long = false
short = false
isLong = false
isShort = false
isLong := isLong[1]
isShort := isShort[1]
orderPrice = priceType == 'stop-limit' ? str.tostring(math.round_to_mintick(close)) + ':' + str.tostring(math.round_to_mintick(close)) + '(S)' : 'market'
tpsl = istpsl ? '|' + str.tostring(tp) + '%|' + str.tostring(sl) + '%' : ''

RSI = ta.rsi(close, 14)


// LONG ------------------------------------------------------------

if not isLong and ta.crossover(RSI, 30)
    long := true
    isLong := true
    isShort := false
    command1 := 'if not long: ' + pair + '(x' + str.tostring(leverage) + '), cancel-close-buy, ' + qty + ', ' + orderPrice + tpsl + ', ' + str.tostring(slot) + ', ' + userkey + ', ' + comment
    alert(command1 + ';' + command2, alert.freq_once_per_bar_close)


// SHORT -----------------------------------------------------------

if not isShort and ta.crossunder(RSI, 70)
    short := true
    isShort := true
    isLong := false
    command1 := 'if not short: ' + pair + '(x' + str.tostring(leverage) + '), cancel-close-sell, ' + qty + ', ' + orderPrice + tpsl + ', ' + str.tostring(slot) + ', ' + userkey + ', ' + comment
    alert(command1 + ';' + command2, alert.freq_once_per_bar_close)


plot(long ? low : na, title='Long', style=plot.style_columns, color=color.rgb(76, 175, 79, 50))
plot(short ? low : na, title='Short', style=plot.style_columns, color=color.rgb(255, 82, 82, 50))